/**-------------------------------------------------------
  *《Flash ActionScript X开发入门》勘误
  * @勘误目的  代码补充注释
  * @page     188--190
  * @version  Created on Dec 7, 2006
  * @author   zhang yafei 
  * @BLOG     http://zhang-yafei.spaces.live.com/
-------------------------------------------------------**/
/**-------------------------------------------------------
  *总体的思路是将Sound对象的属性与GUI模块关联起来
  *我想无论是何种考虑，都无法躲过使用此方法来实现
  *-------------------------------------------------------
  *我利用了一系列变量和onEnterFrame事件配合来达到这个目的
  *另外一些变量用来控制状态：前进、后退、拖动音轨滑块等
  *-------------------------------------------------------
  *  newPosition Sound对象的播放位置，每次播放都检查这个变量
  *  advance 前进
  *  goBack 后退
  *  dragging 拖动音轨滑块
  *  playing 是否正处于播放状态
-------------------------------------------------------**/
//stop()是基于时间轴应用程序最常见的命令
//你随处都可以用它，并且不要吝啬
stop();
//首先声明和初始化变量
var newPosition:Number;
var advance:Boolean;
var goBack:Boolean;
var dragging:Boolean;
var playing:Boolean = true;
butt_play.enabled = false;
//创建Sound的一个实例，然后从库中加载并开始播放
var mySound:Sound = new Sound();
mySound.attachSound(varSound);
mySound.start(0, 1);
//声音播放完毕时，一切复原
mySound.onSoundComplete = function() {
	mysound.stop();
	newPosition = mySound.duration/1000;
	playing = false;
	butt_play.enabled = true;
};
//初始化变量和属性
//音轨属性，主要是用来控制滑块的拖放范围
//startDrag要用这些变量
var fade_track_top:Number = panel_open.fade_track._y;
var fade_track_bottom:Number = panel_open.fade_track._y;
var fade_track_left:Number = panel_open.fade_track._x;
var fade_track_range:Number = panel_open.fade_track._width-1;
var fade_track_right:Number = panel_open.fade_track._x+fade_track_range;
/**
  *GUI按钮的控制事件，主要就是运算几个变量
  *其中主要的就是注意newPosition变量
  *因为这个变量代表的是当前播放的位置
*/
butt_play.onRelease = function() {
	if (!playing && newPosition<mySound.duration) {
		mySound.start(newPosition, 1);
		playing = true;
	}
	butt_stop.enabled = true;
	butt_pause.enabled = true;
	butt_play.enabled = false;
};
butt_pause.onRelease = function() {
	if (playing) {
		newPosition = mySound.position/1000;
	}
	mySound.stop();
	butt_pause.enabled = false;
	butt_stop.enabled = true;
	butt_play.enabled = true;
	playing = false;
};
butt_rewind.onRelease = function() {
	newPosition = 0;
	mySound.stop();
	playing = false;
	panel_open.butt_fade._x = fade_track_left;
	butt_play.onRelease();
	butt_pause.enabled = true;
	butt_stop.enabled = true;
	butt_play.enabled = false;
};
butt_fastforward.onRelease = function() {
	newPosition = 0;
	mySound.stop();
	playing = false;
	butt_play.enabled = true;
	panel_open.butt_fade._x = fade_track_right;
};
butt_stop.onRelease = function() {
	newPosition = 0;
	mySound.stop();
	playing = false;
	panel_open.butt_fade._x = fade_track_left;
	butt_pause.enabled = false;
	butt_stop.enabled = false;
	butt_play.enabled = true;
};
butt_stepforward.onPress = function() {
	advance = true;
};
butt_stepforward.onRelease = function() {
	advance = false;
};
butt_stepforward.onReleaseOutside = function() {
	advance = false;
};
butt_stepBack.onPress = function() {
	goBack = true;
};
butt_stepBack.onRelease = function() {
	goBack = false;
};
butt_stepBack.onReleaseOutside = function() {
	goBack = false;
};
//__________________________________________________________
//利用onEnterFrame事件配合快进和快退按钮命令
//在其中，我们定义了一个变量playing用来显示是否正在播放
//从而根据mySound对象属性来和音轨对应
this.onEnterFrame = function() {
	//注意这里是根据播放的方向来控制的
	//根据不同播放方向来不断改变音轨滑块的位置
	if (advance) {
		if (mySound.position/1000+1<mySound.duration/1000) {
			if (playing) {
				newPosition = mySound.position/1000+1;
				mySound.stop();
				mySound.start(newPosition, 1);
			} else if (butt_fade._x<fade_track_right) {
				butt_fade._x++;
				newPosition = ((panel_open.butt_fade._x/fade_track_range)*mySound.duration)/1000;
			}
		}
	}
	if (goBack) {
		if (playing) {
			newPosition = mySound.position/1000-1;
			mySound.stop();
			mySound.start(newPosition, 1);
		} else if (panel_open.butt_fade._x>fade_track_left) {
			panel_open.butt_fade._x--;
			newPosition = ((panel_open.butt_fade._x/fade_track_range)*mySound.duration)/1000;
		}
	}
	//拖放移动音轨滑块，两个事件      
	//开始拖动和停止拖动
	panel_open.butt_fade.onPress = function() {
		startDrag(panel_open.butt_fade, false, fade_track_left, fade_track_top-5, fade_track_right, fade_track_bottom-5);
		dragging = true;
		playing = false;
	};
	panel_open.butt_fade.onRelease = function() {
		stopDrag();
		mySound.stop();
		dragging = false;
		if (panel_open.butt_fade._x/fade_track_range == 1) {
			playing = false;
			panel_open.butt_fade._x = fade_track_right;
			newPosition = mySound.duration/1000;
		} else {
			playing = true;
			newPosition = (((panel_open.butt_fade._x-fade_track_left)/fade_track_range)*mySound.duration)/1000;
			if (playing) {
				mySound.start(newPosition, 1);
			}
		}
	};
	//音轨滑块自动移动情况
	if (playing) {
		panel_open.butt_fade._x = (mySound.position/mySound.duration)*fade_track_range+fade_track_left;
	}
};

感谢instanceof的来信。
 
 
勘误3（第195-199页，增加代码的注释）、
 
 
/**-------------------------------------------------------
  *《Flash ActionScript X开发入门》勘误
  * @勘误目的  代码补充注释
  * @page     195--199
  * @version  Created on Dec 7, 2006
  * @author   zhang yafei 
  * @BLOG     http://zhang-yafei.spaces.live.com/
-------------------------------------------------------**/
/**-------------------------------------------------------
  *@总体的思路
  *我们使用外部的XML文件来作为MP3文件的数据库
  *主要就是MP3文件的的名称和路径
  *因此下面来构造一个XML对象来加载和解析XML文件
  *目的就是获得MP3文件的的名称和路径
-------------------------------------------------------**/
//soundList是一个列表框组件，用来显示MP3文件
//首先清空组件，也就是一个初始化
//变量myOutSound用来定义是播放库中的声音
//还是播放外部的MP3文件
soundList.removeAll();
_parent._parent.myOutSound = true;
//下面构造一个XML对象来加载和解析XML文件
var xmlSound:XML = new XML();
xmlSound.load("soundlist.xml");
xmlSound.ignoreWhite = true;
function myOnLoad():Void {
	var myVar:String = xmlSound.firstChild.nodeName;
	var myVar2:String = xmlSound.firstChild.firstChild.attributes.path;
	var myVar3:String = xmlSound.firstChild.firstChild.nodeName;
	var myVar4:String = xmlSound.firstChild.firstChild.nextSibling.nodeName;
	var myVar5:String = xmlSound.firstChild.firstChild.firstChild.nodeValue;
	var soundNum:Array = new Array();
	soundNum = xmlSound.firstChild.childNodes;
	for (i=0; i<=soundNum.length; i++) {
		if (soundNum[i].nodeName.substr(0, 5).toLowerCase() == "sound") {
			//填充列表框组件
			soundList.addItem(soundNum[i].firstChild.nodeValue+" in "+soundNum[i].attributes.path, soundNum[i].attributes.path);
		}
	}
	soundInput = soundList.getItemAt(0).data;
	trace(soundList.getItemAt(0).data);
}
xmlSound.onLoad = myOnLoad;
/**-------------------------------------------------------
  *处理用户的选择事件**
  *1、用户选择复选框，表明他将播放库中的声音元件
  *2、用户取消选择复选框，并点击列表框，那么表明将播放外部的MP3文件
  **
  *我们创建两个监听对象以处理用户对复选框和列表框的选择事件
-------------------------------------------------------**/
var myListBox:Object = new Object();
var myCheckBox:Object = new Object();
//为监听对象定义事件函数
//事件函数中有一些向播放器传递消息和命令的代码
//主要就是播放器按钮的状态、播放状态
//变量myOutSound用来定义是播放库中的声音
//还是播放外部的MP3文件
myListBox.change = function(event_obj:Object) {
	soundInput = event_obj.target.selectedItem.data;
	trace(event_obj.target.selectedItem.data);
	_parent._parent.playing = false;
	_parent._parent.mySound.stop();
	_parent._parent.butt_rewind.onRelease();
	_parent._parent.myOutSound = true;
};
myCheckBox.click = function(event_obj:Object) {
	if (event_obj.target.selected) {
		soundList.enabled = false;
		soundInput = "";
		_parent._parent.mySound.stop();
		_parent._parent.playing = false;
		_parent._parent.myOutSound = false;
		_parent._parent.myInSound = true;
		_parent._parent.butt_rewind.onRelease();
	}
	if (!event_obj.target.selected) {
		soundList.enabled = true;
		_parent._parent.mySound.stop();
		_parent._parent.playing = false;
		_parent._parent.myOutSound = true;
		_parent._parent.myInSound = false;
		_parent._parent.butt_rewind.onRelease();
	}
};
//将监听事件函数赋给监听对象
soundList.addEventListener("change", myListBox);
soundCheck.addEventListener("click", myCheckBox);
//stop()是基于时间轴应用程序最常见的命令
//你随处都可以用它，并且不要吝啬
stop();

感谢instanceof的来信。